SGR DrawMap : Différence entre versions

Version du 2 décembre 2013 à 00:33

Paramètres

Paramètres	Type		Description
Paramètres du graphe	Pointeur		Pointeur vers un tableau texte des 14 paramètres généraux de la pyramide Titre du graphe Couleur de fond du graphe Position de la légende (Droite, Gauche ou Centre) Première valeur à tracer Valeur maximum à tracer Nombre de valeur a regrouper Orientation de la pyramide (vertical ou horizontal) Contour des barres (Oui/non) Reflet sur les barres (Oui/non) Format des valeur en bout de barre (%, Valeurs) Espace entre les barres en pixels Affichage d'une échelle de valeur Unité des valeurs Position des valeurs en bout de barre (InSide, OutSide) Police du graphe
valeurs limites	Pointeur		Valeurs limites des palier de valeurs
couleurs	Pointeur		Couleurs à appliquer à la représentation, vous devez définir une couleur de plus que vous n'avez indiqué de valeurs limites
ZoneID	Pointeur		Tableau des ID des zones à mettre en couleur
Value	Pointeur		Valeurs correspondant à chaque ID pour calculer la couleur en fonction des valeurs limites
Resultat	Image		Image incluant le code SVG

Description

Cette commande permet de coloriser un fond de carte en fonction de valeurs et de gradients de couleurs.

Les zones sont répertoriées par leurs ID et manipulées à partir de ceux-ci.

Exemple de code

 // User (OS) : Paul Kuhn - BlueCompany
 // Date  : 08/11/13, 10:42:04
 // ----------------------------------------------------
 // Method : Exemple_carte1
 // Description
 // 
 //
 // Parameters
 // ----------------------------------------------------

TABLEAU TEXTE($DataGrapheName;0)
TABLEAU TEXTE($DataGraphe;0)
AJOUTER A TABLEAU($DataGrapheName;"Title")
AJOUTER A TABLEAU($DataGraphe;"Répartition géographique des ventes")  // 1 - Titre du graphe

AJOUTER A TABLEAU($DataGrapheName;"SVGFile")
AJOUTER A TABLEAU($DataGraphe;"Fond_de_carte_France"+Séparateur dossier+"departements.svg")

AJOUTER A TABLEAU($DataGrapheName;"GraphFont")
AJOUTER A TABLEAU($DataGraphe;"Arial")  // Police des légendes et des échelles

AJOUTER A TABLEAU($DataGrapheName;"GraphBGColor")
AJOUTER A TABLEAU($DataGraphe;"LightBlue:30")  // Couleur du fond

AJOUTER A TABLEAU($DataGrapheName;"ShowLegend")
AJOUTER A TABLEAU($DataGraphe;"Oui")  // Affichage de la légende

AJOUTER A TABLEAU($DataGrapheName;"LegendLanguage")
AJOUTER A TABLEAU($DataGraphe;"English")  // Affichage de la légende

TABLEAU REEL($valeur_limite;3)
$valeur_limite{1}:=30
$valeur_limite{2}:=60
$valeur_limite{3}:=90

TABLEAU TEXTE($couleur;3)
$couleur{0}:="aquamarine"
$couleur{1}:="deepskyblue"
$couleur{2}:="dodgerblue"
$couleur{3}:="midnightblue"

TABLEAU REEL($Value;95)
TABLEAU TEXTE($ZoneID;95)
Boucle ($i;1;95)
$ZoneID{$i}:=Chaine($i;"00")
$Value{$i}:=(Hasard%(101))
Fin de boucle 
$ZoneID{20}:="2A"
INSERER DANS TABLEAU($ZoneID;21;1)
$ZoneID{21}:="2B"
INSERER DANS TABLEAU($Value;21;1)
$Value{21}:=$Value{20}

TheGraphe:=SGR_DrawMap (->$DataGrapheName;->$DataGraphe;->$valeur_limite;->$couleur;->$ZoneID;->$Value)

• 

  Image correspondant à l'exemple de code ci-dessus